Wikia

Request Tracker Wiki

AutoreplyOrCorrespondence

Comments0
858pages on
this wiki

This template code checks to see if the creator is the same as one of the requestors on ticket creation. If so it loads and processes the Autoreply template searching first in the current queue and if there isn't one there resorting to the global version.

If the requestor is not the creator then it processes the Correspondence template instead doing the same search as above.

The effect of using this template is that if a ticket is created on behalf of a customer they receive the message you create (on ticket creation) as if it is a reply rather than the default cryptic auto-reply.

It assumes there are at least global templates 'Autoreply' and 'Correspondence'.


    {
      use RT::Template;
      my $creator_name = $Ticket->CreatorObj->Name;
      my $requestors = $Ticket->Requestors->UserMembersObj;
      my ( $c_requestor, $r_count ) = ( 0, 0 );
      while ( my $r = $requestors->Next() ) {
          if ( $r->Name eq $creator_name ) {
              $c_requestor++;
          }
          else {
              $r_count++;
          }
      }
      my $template = new RT::Template($RT::SystemUser);
      my $template_name;
      
      #if the creator is not a requestor or 
      #there is more than one requestor ( who's not the creator )
      #use the Correspondence template
      if ( ! $c_requestor || $r_count ) {
          $template_name = 'Correspondence';
      }
      else {
          #otherwise use the Autoreply template
          $template_name = 'Autoreply';
      }
  
      #Load the Queue Template
      $template->LoadQueueTemplate( 
          Queue => $Ticket->Queue, 
          Name => $template_name,
      );
      #if there's no Queue Template attempt to find a Global one.
      unless ( $template->id ) {
          $template->LoadGlobalTemplate( $template_name );
          unless ( $template->id ) { 
              $RT::Logger->error("Could not load template : $template_name")
          }
      }
      #Process embedded fields & expressions of true templates;
      #note that we can only meaningfully use the body
      my($ret, $msg) = $template->Parse(
                           TicketObj => $Ticket, 
                           TransactionObj => $Transaction,
                       );
      $ret ? $template->MIMEObj->stringify : $msg;
    }
   

Around Wikia's network

Random Wiki